ClockSync

Halten Sie Ihre Windows-Uhr synchronisiert.

ClockSync ist ein einfaches Befehlszeilenskript, um Ihre Windows-Uhr zu synchronisieren.
In einigen Systemen und aus verschiedenen Gründen kann die Windows-Uhr häufig nicht mehr synchron sein.
Dieses kleine Tool sollte dieses Problem lösen.
ClockSync ist in Batch-Sprache geschrieben.

Wenn Sie nach einem Programm suchen, um Ihre Systemzeit genau zu halten, haben Sie es gerade gefunden!

  • Frei
  • Open Source
  • Klein: weniger als 2 kb
  • Schnell und einfach zu bedienen
  • Funktioniert auf jedem Windows von Win7 bis Win10, einschließlich Server-Editionen.
    Es werden sowohl 32-Bit- als auch 64-Bit-Betriebssysteme unterstützt.
Verwendung:
  1. Stellen Sie sicher, dass Sie mit dem Internet verbunden sind.
  2. Führen Sie die Datei ClockSync.bat mit Administratorrechten aus.

ClockSync führt automatisch eine erste Synchronisation durch.
Danach führt es periodische Synchronisationen in einem Zeitintervall durch.
Standardmäßig wird die Zeit alle 10 Minuten synchronisiert.

Wenn Sie eine angeben möchten benutzerdefiniertes Resynchronisierungsintervall, führen Sie die Datei mit einem „Minuten“-Befehlsparameter aus.
Der folgende Befehl zum Beispiel synchronisiert die Uhr alle 60 Minuten:
„ClockSync.bat 60“

Details:

ClockSync hält Ihre Systemuhr genau, indem es regelmäßige Synchronisierungen mit Ihrem standardmäßigen Internet-Zeitserver durchführt.

Wenn der Windows-Zeitdienst oder die Internet-Zeitsynchronisierung deaktiviert waren, wird ClockSync sie neu starten.
Dies trägt dazu bei, dass Ihre Systemuhr auch dann genau bleibt, wenn ClockSync nicht ausgeführt wird.

Quellcode:

ClockSync.bat :

@echo off
echo * ClockSync v1.0
echo * BreakingSecurity.net
echo.
:: Check that we own administrator access level. 
echo [INFO] Checking Access Level...
net session >nul 2>&1
if %errorLevel% == 0 (
	:: We have the necessary rights, go forward
	echo [INFO] Administrative Access confirmed.
) else (
	:: Error, insufficient privileges. Exit program.
	echo [ERROR] Insufficient Access Level. Please restart script with administrative permission.
	echo.
	echo Press any key to exit...
	pause > nul
	exit
)
:: Check command-line parameter.
:: User can specify any number of minutes for the Resync interval.
:: If there is no user-specified parameter, default one is used.
set /A minutes = 10
if not "%1" == "" (
	set /A minutes=%1
)
:loop
:: Synchronize Clock
:: Use /force parameter to bypass "time change too big" error
w32tm /resync /force
if not errorlevel 0 (
	:: If Error, restart time service
    echo [WARNING] Time Service error. Restarting service...
	net stop w32time
    w32tm /unregister
    w32tm /register
    net start w32time
	w32tm /resync /force
	if not errorlevel 0 (
		:: Unknown error, exit program.
		echo [ERROR] Unknown error.
		echo.
		echo Press any key to exit...
		pause > nul
		exit
	)
)
echo.
echo [SUCCESS] Clock successfully synchronized!
echo Date: %date%
echo Time: %time%
echo.
:: Sleep
set /A seconds = %minutes% * 60
echo [INFO] Sleeping for %minutes% minutes until next synchronization...
echo.
ping 127.0.0.1 -n %seconds% > nul
:: Repeat
goto loop
Menü